DllCall()

Result := DllCall("DllFile\Function" , Type1, Arg1, Type2, Arg2, "Cdecl ReturnType")

Ptr := A_PtrSize ? "Ptr" : "UInt" ; A_PtrSize가 정의되어 있지 않으면 대신 UInt를 사용합니다.
DllCall("DeleteFile", Ptr, &filename) ; Ptr 둘레에 인용 부호를 생략합니다.

hModule := DllCall("LoadLibrary", "Str", "MyFunctions.dll", "Ptr")  ; 회돌이 안에서 DllCall()이 라이브러리를 적재할 필요가 없습니다.
Loop, C:\My Documents\*.*, , 1
    result := DllCall("MyFunctions\BackupFile", "Str", A_LoopFileFullPath)
DllCall("FreeLibrary", "Ptr", hModule)  ; 메모리를 절약하기 위해, DLL은 사용한 다음 내려도 됩니다.

; 다음 예제에서, DLL이 아직 적재되지 않았다면, GetModuleHandle 대신 LoadLibrary를 사용합니다.
MulDivProc := DllCall("GetProcAddress", "Ptr", DllCall("GetModuleHandle", "Str", "kernel32", "Ptr"), "AStr", "MulDiv", "Ptr")
Loop 500
    DllCall(MulDivProc, "Int", 3, "Int", 4, "Int", 3)

MyVar := "ABC"
result := DllCall("CharLower", "Str", DllCall("CharUpper", "Str", MyVar, "Str"), "Str")

Windows API 함수 "MessageBox"를 호출하고 사용자가 누른 버튼을 보고합니다.

WhichButton := DllCall("MessageBox", "Int", 0, "Str", "Press Yes or No", "Str", "Title of box", "Int", 4)
MsgBox You pressed button #%WhichButton%.

바탕화면 화면을 지정된 비트맵 파일로 바꿉니다 (.bmp).

DllCall("SystemParametersInfo", "UInt", 0x14, "UInt", 0, "Str", A_WinDir . "\winnt.bmp", "UInt", 1)

API 함수 "IsWindowVisible"를 호출해 노트패드 창이 보이는지 알아냅니다.

DetectHiddenWindows On
if not DllCall("IsWindowVisible", "Ptr", WinExist("Untitled - Notepad"))  ; WinExist() returns an HWND.
    MsgBox The window is not visible.

API의 wsprintf()를 호출해 432 숫자 앞에 0을 덧대어 10 자리 너비의 문자로 만듭니다 (0000000432).

VarSetCapacity(ZeroPaddedNumber, 20)  ; 변수가 새 문자열을 받을 만큼 충분히 큰지 확인합니다.
DllCall("wsprintf", "Str", ZeroPaddedNumber, "Str", "%010d", "Int", 432, "Cdecl")  ; Cdecl 호출 관례를 요구합니다.
MsgBox %ZeroPaddedNumber%

; [v1.1.17+]: The same can be achieved via Format function in conjunction with the zero flag:
MsgBox % Format("{:010}", 432)

QueryPerformanceCounter()의 사용법을 보여줍니다. A_TickCount의 10ms 보다 더 정밀도가 높습니다.

DllCall("QueryPerformanceFrequency", "Int64*", freq)
DllCall("QueryPerformanceCounter", "Int64*", CounterBefore)
Sleep 1000
DllCall("QueryPerformanceCounter", "Int64*", CounterAfter)
MsgBox % "Elapsed QPC time is " . (CounterAfter - CounterBefore) / freq * 1000 " ms"

Press a hotkey to temporarily reduce the mouse cursor's speed, which facilitates precise positioning. F1를 누르면 커서의 속도가 느려집니다. 떼면 원래의 속도로 돌아옵니다.

F1::
SPI_GETMOUSESPEED := 0x70
SPI_SETMOUSESPEED := 0x71
; 나중에 복구할 수 있도록 현재 속도를 열람합니다:
DllCall("SystemParametersInfo", "UInt", SPI_GETMOUSESPEED, "UInt", 0, "UIntP", OrigMouseSpeed, "UInt", 0)
; 이제 마우스를 더 느린 속도로 지정합니다. 가장 마지막 매개변수 바로 앞에 지정되어 있습니다 (범위는  1-20이고, 10이 기본값입니다):
DllCall("SystemParametersInfo", "UInt", SPI_SETMOUSESPEED, "UInt", 0, "Ptr", 3, "UInt", 0)
KeyWait F1  ; 키보드 자동 반복 때문에 DllCall이 반복적으로 호출되는 것을 방지합니다.
return

F1 up::DllCall("SystemParametersInfo", "UInt", SPI_SETMOUSESPEED, "UInt", 0, "Ptr", OrigMouseSpeed, "UInt", 0)  ; 원래 속도를 복구합니다

활성 창을 관제하고 초점이 있는 콘트롤 안에서 그의 수직 스크롤바의 위치를 (실시간으로 갱신하여) 보여줍니다. 이것은 [v1.0.43.06+]을 요구합니다. 왜냐하면 ControlGet Hwnd를 사용하기 때문입니다.

#Persistent
SetTimer, WatchScrollBar, 100
return

WatchScrollBar:
ActiveWindow := WinExist("A")
if not ActiveWindow  ; No active window.
    return
ControlGetFocus, FocusedControl, ahk_id %ActiveWindow%
if not FocusedControl  ; No focused control.
    return
; 툴팁에 수평 또는 수직 스크롤바의 위치를 보여줍니다:
ControlGet, ChildHWND, Hwnd,, %FocusedControl%, ahk_id %ActiveWindow%
ToolTip % DllCall("GetScrollPos", "Ptr", ChildHWND, "Int", 1)  ;  마지막 매개변수는 SB_VERT에 대해 1 for, SB_HORZ에 대해 0입니다.
return

텍스트를 파일에 쓴다음 다시 메모리로 읽어 들입니다 ([v1.0.34+] 요구). 이 메쏘드를 사용하면 여러 파일을 동시에 읽거나 쓸 경우 수행성능이 향상 됩니다. [AHK_L 42+]: FileOpen()을 사용하면, 같은 일을 할 수 있습니다.

FileSelectFile, FileName, S16,, Create a new file:
if (FileName = "")
    return
GENERIC_WRITE := 0x40000000  ; 읽기가 아니라 쓰기 용도로 파일을 엽니다.
CREATE_ALWAYS := 2  ; 새 파일을 만듭니다 (기존의 파일을 덮어씀).
hFile := DllCall("CreateFile", "Str", FileName, "UInt", GENERIC_WRITE, "UInt", 0, "Ptr", 0, "UInt", CREATE_ALWAYS, "UInt", 0, "Ptr", 0, "Ptr")
if not hFile
{
    MsgBox Can't open "%FileName%" for writing.
    return
}
TestString := "This is a test string.`r`n"  ; 파일을 이런 식으로 쓸 때,  `n 말고 `r`n을 사용하여 새 줄을 시작하십시오.
StrLen := StrLen(TestString) * (A_IsUnicode ? 2 : 1)
DllCall("WriteFile", "Ptr", hFile, "Str", TestString, "UInt", StrLen, "UIntP", BytesActuallyWritten, "Ptr", 0)
DllCall("CloseHandle", "Ptr", hFile)  ; 파일을 닫습니다.

; 파일에 썼으므로 이제 다시 그 내용을 메모리로 읽어 들입니다.
GENERIC_READ := 0x80000000  ; 쓰기 말고 읽기 용도로 파일을 엽니다.
OPEN_EXISTING := 3  ; 이 모드는 열릴 파일이 이미 존재해야 함을 가리킵니다.
FILE_SHARE_READ := 0x1 ; This and the next are whether other processes can open the file while we have it open.
FILE_SHARE_WRITE := 0x2
hFile := DllCall("CreateFile", "Str", FileName, "UInt", GENERIC_READ, "UInt", FILE_SHARE_READ|FILE_SHARE_WRITE, "Ptr", 0, "UInt", OPEN_EXISTING, "UInt", 0, "Ptr", 0)
if not hFile
{
    MsgBox Can't open "%FileName%" for reading.
    return
}
; 테스트 목적으로 변수를 비우지만, 가용 능력이 충분한지 확인하십시오:
BytesToRead := VarSetCapacity(TestString, StrLen)
DllCall("ReadFile", "Ptr", hFile, "Str", TestString, "UInt", BytesToRead, "UIntP", BytesActuallyRead, "Ptr", 0)
DllCall("CloseHandle", "Ptr", hFile)  ; 파일을 닫습니다.
MsgBox The following string was read from the file: %TestString%

Win+C를 누를 때 마우스 커서를 감춥니다. To later show the cursor, press this hotkey again. 스크립트는 www.autohotkey.com/forum/topic6107.html에서 얻을 수 있습니다.

OnExit, ShowCursor  ; 스크립트가 종료할 때 커서가 보이는지 확인합니다.
return

ShowCursor:
SystemCursor("On")
ExitApp

#c::SystemCursor("Toggle")  ; Win+C 핫키로 커서를 켜고 끕니다.

SystemCursor(OnOff=1)   ; INIT = "I","Init"; OFF = 0,"Off"; TOGGLE = -1,"T","Toggle"; ON = others
{
    static AndMask, XorMask, $, h_cursor
        ,c0,c1,c2,c3,c4,c5,c6,c7,c8,c9,c10,c11,c12,c13 ; 시스템 커서
        , b1,b2,b3,b4,b5,b6,b7,b8,b9,b10,b11,b12,b13   ; 빈 커서
        , h1,h2,h3,h4,h5,h6,h7,h8,h9,h10,h11,h12,h13   ; 기본 커서의 핸들
    if (OnOff = "Init" or OnOff = "I" or $ = "")       ; 요청될 때 또는 첫 번째로 호출될 때 초기화합니다
    {
        $ := "h"                                       ; 기본 커서를 활성화합니다
        VarSetCapacity( h_cursor,4444, 1 )
        VarSetCapacity( AndMask, 32*4, 0xFF )
        VarSetCapacity( XorMask, 32*4, 0 )
        system_cursors := "32512,32513,32514,32515,32516,32642,32643,32644,32645,32646,32648,32649,32650"
        StringSplit c, system_cursors, `,
        Loop %c0%
        {
            h_cursor   := DllCall( "LoadCursor", "Ptr",0, "Ptr",c%A_Index% )
            h%A_Index% := DllCall( "CopyImage", "Ptr",h_cursor, "UInt",2, "Int",0, "Int",0, "UInt",0 )
            b%A_Index% := DllCall( "CreateCursor", "Ptr",0, "Int",0, "Int",0
                , "Int",32, "Int",32, "Ptr",&AndMask, "Ptr",&XorMask )
        }
    }
    if (OnOff = 0 or OnOff = "Off" or $ = "h" and (OnOff < 0 or OnOff = "Toggle" or OnOff = "T"))
        $ := "b"  ; 빈 커서를 사용합니다
    else
        $ := "h"  ; 저장된 커서를 사용합니다

    Loop %c0%
    {
        h_cursor := DllCall( "CopyImage", "Ptr",%$%%A_Index%, "UInt",2, "Int",0, "Int",0, "UInt",0 )
        DllCall( "SetSystemCursor", "Ptr",h_cursor, "UInt",c%A_Index% )
    }
}

구조체 예제. RECT 구조체의 주소를 GetWindowRect()에 건넵니다. 구조체의 멤버가 창의 좌, 상, 우, 하의 위치에 설정됩니다 (화면에 상대적임).

Run Notepad
WinWait Untitled - Notepad  ; This also sets the "last found window" for use with WinExist() below.
VarSetCapacity(Rect, 16)  ; A RECT is a struct consisting of four 32-bit integers (i.e. 4*4=16).
DllCall("GetWindowRect", "Ptr", WinExist(), "Ptr", &Rect)  ; WinExist() returns an HWND.
MsgBox % "Left " . NumGet(Rect, 0, "Int") . " Top " . NumGet(Rect, 4, "Int")
    . " Right " . NumGet(Rect, 8, "Int") . " Bottom " . NumGet(Rect, 12, "Int")

구조체 예제. FillRect()에 RECT 구조체의 주소를 건넵니다. 이 구조체는 임시로 빨갛게 칠할 화면의 구역을 가리킵니다.

VarSetCapacity(Rect, 16, 0)  ; 4-바이트 정수를 수용하도록 가용능력을 설정하고 그 모두를 0으로 초기화합니다.
NumPut(A_ScreenWidth//2, Rect, 8, "Int")  ; 구조체에서 세 번째 정수는 "rect.right"입니다.
NumPut(A_ScreenHeight//2, Rect, 12, "Int") ; 구조체에서 네 번째 정수는 "rect.bottom"입니다.
hDC := DllCall("GetDC", "Ptr", 0, "Ptr")  ; 0을 건네 데스크탑의 장치 문맥을 얻습니다.
hBrush := DllCall("CreateSolidBrush", "UInt", 0x0000FF, "Ptr")  ; 빨간색 브러쉬를 만듭니다 (BGR 형식으로 0x0000FF 임).
DllCall("FillRect", "Ptr", hDC, "Ptr", &Rect, "Ptr", hBrush)  ; 지정된 사각구역을 위의 브러쉬를 사용하여 채웁니다.
DllCall("ReleaseDC", "Ptr", 0, "Ptr", hDC)  ; 청소.
DllCall("DeleteObject", "Ptr", hBrush)  ; 청소.

구조체 예제. 시스템 시계를 지정된 날짜와 시간으로 설정합니다. 앞으로 날짜를 변경할 때 주의하십시오. 일정이 잡혀 있는 작업이 너무 이르게 실행될 가능성이 있습니다!

SetSystemTime("20051008142211")  ; 시간도장을 건넵니다 (지역시간입니다. UTC아님).

SetSystemTime(YYYYMMDDHHMISS)
; 시스템 시계를 지정된 날짜와 시간으로 설정합니다.
; 호출자는 들어오는 매개변수가 유효한 날짜-시간 도장인지 확인해야 합니다
; (지역시간이지, UTC 시간이 아닙니다). 성공하면 0-아닌 값을 돌려주고 그렇지 않으면 0을 돌려줍니다.
{
    ; SetSystemTime()에 사용하기 위해 매개변수를 지역 시간에서  UTC 시간으로 변경합니다.
    UTC_Delta -= A_NowUTC, Seconds  ; 반올림 문제 때문에 초가 더 정확합니다.
    UTC_Delta := Round(-UTC_Delta/60)  ; 가장 가까운 분으로 반올림해 정확도를 확인합니다.
    YYYYMMDDHHMISS += UTC_Delta, Minutes  ; UTC로 변환하기 위해 오프셋을 적용합니다.

    VarSetCapacity(SystemTime, 16, 0)  ; 이 구조는 8개의 UShort로 구성됩니다(즉, 8*2=16).

    Int := SubStr(YYYYMMDDHHMISS, 1, 4)  ; YYYY (해)
    NumPut(Int, SystemTime, 0, "UShort")
    Int := SubStr(YYYYMMDDHHMISS, 5, 2)  ; MM (달, 1-12)
    NumPut(Int, SystemTime, 2, "UShort")
    Int := SubStr(YYYYMMDDHHMISS, 7, 2)  ; DD (날)
    NumPut(Int, SystemTime, 6, "UShort")
    Int := SubStr(YYYYMMDDHHMISS, 9, 2)  ; HH (24-시간제 시간)
    NumPut(Int, SystemTime, 8, "UShort")
    Int := SubStr(YYYYMMDDHHMISS, 11, 2) ; MI (분)
    NumPut(Int, SystemTime, 10, "UShort")
    Int := SubStr(YYYYMMDDHHMISS, 13, 2) ; SS (초)
    NumPut(Int, SystemTime, 12, "UShort")

    return DllCall("SetSystemTime", "Ptr", &SystemTime)
}

고급 구조체 예제:

• DllCall()을 사용하여 TCP/IP 서버에 네트워크 접속을 만들고 그로부터 데이터를 받는 방법은 WinLIRC 클라이언트 스크립트를 참조하십시오.
• 운영 체제는 사용자가 글꼴이나 컬러 또는 아이콘을 고를 수 있도록 표준 대화상자를 제공합니다. 이런 대화상자는 구조체를 사용하고 GitHub에서 예를 보실 수 있습니다.

COM을 사용하여 임시로 활성 창을 태스크바에서 제거합니다.

/*
  ITaskbarList의 VTable에 있는 메쏘드:
    IUnknown:
      0 QueryInterface  -- 대신 ComObjQuery()를 사용하십시오
      1 AddRef          -- 대신 ObjAddRef() 를 사용하십시오
      2 Release         -- 대신use ObjRelease() 를 사용하십시오
    ITaskbarList:
      3 HrInit
      4 AddTab
      5 DeleteTab
      6 ActivateTab
      7 SetActiveAlt
*/
IID_ITaskbarList  := "{56FDF342-FD6D-11d0-958A-006097C9A090}"
CLSID_TaskbarList := "{56FDF344-FD6D-11d0-958A-006097C9A090}"

; TaskbarList 객체를 만들고 그의 주소를 tbl에 저장합니다.
tbl := ComObjCreate(CLSID_TaskbarList, IID_ITaskbarList)

activeHwnd := WinExist("A")

DllCall(vtable(tbl,3), "ptr", tbl)                     ; tbl.HrInit()
DllCall(vtable(tbl,5), "ptr", tbl, "ptr", activeHwnd)  ; tbl.DeleteTab(activeHwnd)
Sleep 3000
DllCall(vtable(tbl,4), "ptr", tbl, "ptr", activeHwnd)  ; tbl.AddTab(activeHwnd)

; 분배가 없는 객체는 언제나 수작업으로 해제해야 합니다.
ObjRelease(tbl)

vtable(ptr, n) {
    ; NumGet(ptr+0)은 그 객체의 가상 함수 테이블의 (약자로 vtable)
    ; 주소를 돌려줍니다. 표현식의 나머지는 n번째 함수의 주소를
    ; vtable로부터 열람합니다.
    return NumGet(NumGet(ptr+0), n*A_PtrSize)
}