ComCall - 構文と使用法

COMのネイティブインターフェースメソッドをインデックスで呼び出します。

パラメータ

戻り値

ReturnTypeがHRESULT（または省略）で、メソッドがエラー値を返した場合（FAILED マクロで定義）、OSErrorがスローされます。

そうでない場合、ComCallは、メソッドによって返された実際の値を返します。メソッドが値を返さない型（Cで定義された戻り値の型がvoid）の場合、結果は未定義であり、無視されるべきです。

備考

関連

例

アクティブなウィンドウを3秒間、タスクバーから削除します。同等のDllCallの例と比較してみてください。

/*
  ITaskbarListのVTableにあるメソッドです：
    IUnknown:
      0 QueryInterface  -- ComObjQueryの代わりに使用
      1 AddRef          -- ObjAddRefの代わりに使用
      2 Release         -- ObjReleaseの代わりに使用
    ITaskbarList:
      3 HrInit
      4 AddTab
      5 DeleteTab
      6 ActivateTab
      7 SetActiveAlt
*/
IID_ITaskbarList  := "{56FDF342-FD6D-11d0-958A-006097C9A090}"
CLSID_TaskbarList := "{56FDF344-FD6D-11d0-958A-006097C9A090}"

; TaskbarListオブジェクトを作成します。
tbl := ComObject(CLSID_TaskbarList, IID_ITaskbarList)

activeHwnd := WinExist("A")

ComCall(3, tbl)                     ; tbl.HrInit()
ComCall(5, tbl, "ptr", activeHwnd)  ; tbl.DeleteTab(activeHwnd)
Sleep 3000
ComCall(4, tbl, "ptr", activeHwnd)  ; tbl.AddTab(activeHwnd)

; When finished with the object, simply replace any references with
; some other value (or if its a local variable, just return):
tbl := ""

COMインタフェースをラッピングするいくつかのテクニックを実証します。前例に準ずる。

tbl := TaskbarList()

activeHwnd := WinExist("A")

tbl.DeleteTab(activeHwnd)
Sleep 3000
tbl.AddTab(activeHwnd)

tbl := ""


class TaskbarList {
    static IID := "{56FDF342-FD6D-11d0-958A-006097C9A090}"
    static CLSID := "{56FDF344-FD6D-11d0-958A-006097C9A090}"
    
    ; クラスを初期化するために起動時に呼び出されます。
    static __new() {
        ; TaskbarList のすべてのインスタンスのベースオブジェクトを取得します。
        proto := this.Prototype
        
        ; Bound関数でパラメータを事前に定義することができます。
        ; ラッパー関数を必要とせず、より使いやすいメソッドを提供します。
        ; HrInit自身はパラメータを持たないので、インデックスだけをバインドします。
        ; であり、呼び出し側は暗黙のうちに 'this' を提供することになる。
        proto.HrInit := ComCall.Bind(3)
        
        ; パラメータを空白にすることで、呼び出し側が値を指定できるようにします。
        ; この場合、空白のパラメータは'this'（通常は非表示）です。
        proto.AddTab := ComCall.Bind(4,, "ptr")
        
        ; オブジェクトやMapを使用することで、繰り返しを減らすことができます。
        for name, args in Map(
            "DeleteTab", [5,,"ptr"],
            "ActivateTab", [6,,"ptr"],
            "SetActiveAlt", [7,,"ptr"]) {
            proto.%name% := ComCall.Bind(args*)
        }
    }
    
    ; 新しいインスタンスに対して TaskbarList() によって呼び出されます。
    __new() {
        this.comobj := ComObject(TaskbarList.CLSID, TaskbarList.IID)
        this.ptr := this.comobj.ptr
        ; ITaskbarList を介してリクエストを初期化します。
        this.HrInit()
    }
}