DllCall

Result := DllCall("DllFile\Function" , Type1, Arg1, Type2, Arg2, "Cdecl ReturnType")

buf := Buffer(length)  ; 一時的なバッファを確保します。
DllCall("Function", "ptr", buf)  ; バッファを関数に渡す。
str := StrGet(buf, "cp0")  ; バッファからANSI文字列を取得します。

hModule := DllCall("LoadLibrary", "Str", "MyFunctions.dll", "Ptr")  ; ループ内でDllCallしてライブラリを読み込む必要を回避。
Loop Files, "C:\My Documents\*.*", "R"
    result := DllCall("MyFunctions\BackupFile", "Str", A_LoopFilePath)
DllCall("FreeLibrary", "Ptr", hModule)  ; メモリ節約のため、使用後はDLLをアンロードすることがあります。

; 次の例では、DLLがまだロードされていない場合、GetModuleHandleの代わりにLoadLibraryを使用してください。
MulDivProc := DllCall("GetProcAddress", "Ptr", DllCall("GetModuleHandle", "Str", "kernel32", "Ptr"), "AStr", "MulDiv", "Ptr")
Loop 500
    DllCall(MulDivProc, "Int", 3, "Int", 4, "Int", 3)

MyVar := "ABC"
result := DllCall("CharLower", "Str", DllCall("CharUpper", "Str", MyVar, "Str"), "Str")

Windows API関数 "MessageBox"を呼び出し、ユーザーがどのボタンを押したかを報告します。

WhichButton := DllCall("MessageBox", "Int", 0, "Str", "Press Yes or No", "Str", "Title of box", "Int", 4)
MsgBox "You pressed button #" WhichButton

デスクトップの壁紙を、指定したビットマップ（.bmp）ファイルに変更します。

DllCall("SystemParametersInfo", "UInt", 0x14, "UInt", 0, "Str", A_WinDir . "\winnt.bmp", "UInt", 1)

API関数 "IsWindowVisible"を呼び出し、メモ帳ウィンドウが表示されているかどうかを調べる。

DetectHiddenWindows True
if not DllCall("IsWindowVisible", "Ptr", WinExist("Untitled - Notepad"))  ; WinExistはHWNDを返す。
    MsgBox "The window is not visible."

APIのwsprintf()を呼び出し、数字432に先頭のゼロをパッドして10文字幅(0000000432)にします。

ZeroPaddedNumber := Buffer(20)  ; バッファが新しい文字列を受け入れるのに十分な大きさであることを確認します。
DllCall("wsprintf", "Ptr", ZeroPaddedNumber, "Str", "%010d", "Int", 432, "Cdecl")  ; Cdecl の呼び出し規約を必要とします。
MsgBox StrGet(ZeroPaddedNumber)

; または、Format関数とゼロフラグを組み合わせて使用します：
MsgBox Format("{:010}", 432)

Demonstrates QueryPerformanceCounter(), which gives more precision than A_TickCount's 10 ms.

DllCall("QueryPerformanceFrequency", "Int64*", &freq := 0)
DllCall("QueryPerformanceCounter", "Int64*", &CounterBefore := 0)
Sleep 1000
DllCall("QueryPerformanceCounter", "Int64*", &CounterAfter := 0)
MsgBox "Elapsed QPC time is " . (CounterAfter - CounterBefore) / freq * 1000 " ms"

ホットキーを押すと、マウスカーソルの速度が一時的に低下し、正確な位置決めがしやすくなります。F1を押し続けると、カーソルが遅くなる。離すと元の速度に戻ります。

F1::
F1 up::
{
    static SPI_GETMOUSESPEED := 0x70
    static SPI_SETMOUSESPEED := 0x71
    static OrigMouseSpeed := 0
    
switch ThisHotkey
    {
    case "F1":
        ; 現在の速度を取得し、後で復元できるようにする：
        DllCall("SystemParametersInfo", "UInt", SPI_GETMOUSESPEED, "UInt", 0, "Ptr*", &OrigMouseSpeed, "UInt", 0)
        ; ここで、マウスの速度を、最後から2番目のパラメータで指定された遅い速度に設定します（範囲は1～20、10がデフォルト）：
        DllCall("SystemParametersInfo", "UInt", SPI_SETMOUSESPEED, "UInt", 0, "Ptr", 3, "UInt", 0)
        KeyWait "F1"  ; キーボードのオートリピートがDllCallを繰り返し実行するのを防ぐことができます。
        
case "F1 up":
DllCall("SystemParametersInfo", "UInt", SPI_SETMOUSESPEED, "UInt", 0, "Ptr", OrigMouseSpeed, "UInt", 0)  ; 元の速度に戻す。
    }
}

アクティブなウィンドウを監視し、その垂直スクロールバーの位置をフォーカスコントロールに表示します（リアルタイムに更新されます）。

SetTimer WatchScrollBar, 100

WatchScrollBar()
{
    FocusedHwnd := 0
    try FocusedHwnd := ControlGetFocus("A")
    if !FocusedHwnd  ; フォーカスされたコントロールがない。
        return
    ; 縦または横スクロールバーの位置をツールチップに表示する：
    ToolTip DllCall("GetScrollPos", "Ptr", FocusedHwnd, "Int", 1)  ; SB_VERTの場合は1、SB_HORZの場合は0になります。
}

ファイルにテキストを書き、それをメモリに読み戻す。この方法は、複数のファイルを同時に読み書きするような場合に、パフォーマンスを向上させるために使用することができます。また、FileOpenを使用しても同様の効果を得ることができます。

FileName := FileSelect("S16",, "Create a new file:")
if FileName = ""
    return
GENERIC_WRITE := 0x40000000  ; 読み出しではなく、書き込みのためにファイルを開く。
CREATE_ALWAYS := 2  ; 新規ファイルを作成します（既存のファイルを上書きします）。
hFile := DllCall("CreateFile", "Str", FileName, "UInt", GENERIC_WRITE, "UInt", 0, "Ptr", 0, "UInt", CREATE_ALWAYS, "UInt", 0, "Ptr", 0, "Ptr")
if !hFile
{
    MsgBox "Can't open '" FileName "' for writing."
    return
}
TestString := "This is a test string.`r`n"  ; この方法でファイルを書く場合、改行には `n ではなく `r`n を使用します。
StrSize := StrLen(TestString) * 2
DllCall("WriteFile", "Ptr", hFile, "Str", TestString, "UInt", StrSize, "UIntP", &BytesActuallyWritten := 0, "Ptr", 0)
DllCall("CloseHandle", "Ptr", hFile)  ; ファイルを閉じる。

; ファイルが書き込まれたので、その内容をメモリに読み返してください。
GENERIC_READ := 0x80000000  ; 書き込みではなく、読み込みのためにファイルを開く。
OPEN_EXISTING := 3  ; このモードは、オープンするファイルが既に存在することを示します。
FILE_SHARE_READ := 0x1 ; こちらがファイルを開いている間に、他のプロセスがファイルを開くことができるかどうかです。
FILE_SHARE_WRITE := 0x2
hFile := DllCall("CreateFile", "Str", FileName, "UInt", GENERIC_READ, "UInt", FILE_SHARE_READ|FILE_SHARE_WRITE, "Ptr", 0, "UInt", OPEN_EXISTING, "UInt", 0, "Ptr", 0)
if !hFile
{
    MsgBox "Can't open '" FileName "' for reading."
    return
}
; 文字列を読み込むためのメモリブロックを確保する：
Buf := Buffer(StrSize)
DllCall("ReadFile", "Ptr", hFile, "Ptr", Buf, "UInt", Buf.Size, "UIntP", &BytesActuallyRead := 0, "Ptr", 0)
DllCall("CloseHandle", "Ptr", hFile)  ; ファイルを閉じる。
MsgBox "The following string was read from the file:" StrGet(Buf)

Win+Cを押したときに、マウスカーソルを隠す。後でカーソルを表示させるには、このホットキーをもう一度押してください。

OnExit (*) => SystemCursor("Show")  ; スクリプト終了時にカーソルが表示されるようにします。

#c::SystemCursor("Toggle")  ; Win+CホットキーでカーソルのON/OFFを切り替えられます。

SystemCursor(cmd)  ; cmd = "Show|Hide|Toggle|Reload"
{
    static visible := true, c := Map()
    static sys_cursors := [32512, 32513, 32514, 32515, 32516, 32642
                         , 32643, 32644, 32645, 32646, 32648, 32649, 32650]
    if (cmd = "Reload" or !c.Count)  ; リクエスト時またはファーストコール時にリロードします。
    {
        for i, id in sys_cursors
        {
            h_cursor  := DllCall("LoadCursor", "Ptr", 0, "Ptr", id)
            h_default := DllCall("CopyImage", "Ptr", h_cursor, "UInt", 2
                , "Int", 0, "Int", 0, "UInt", 0)
            h_blank   := DllCall("CreateCursor", "Ptr", 0, "Int", 0, "Int", 0
                , "Int", 32, "Int", 32
                , "Ptr", Buffer(32*4, 0xFF)
                , "Ptr", Buffer(32*4, 0))
            c[id] := {default:h_default, blank:h_blank}
        }
    }
    switch cmd
    {
    case "Show":visible := true
    case "Hide":visible := false
    case "Toggle":visible := !visible
    default:return
    }
    for id, handles in c
    {
        h_cursor := DllCall("CopyImage"
            , "Ptr", visible ? handles.default : handles.blank
            , "UInt", 2, "Int", 0, "Int", 0, "UInt", 0)
        DllCall("SetSystemCursor", "Ptr", h_cursor, "UInt", id)
    }
}

構造例です。RECT構造体のアドレスをGetWindowRect()に渡すと、構造体のメンバーにウィンドウの左、上、右、下辺の位置（画面に対する相対位置）が設定されます。

Run "Notepad"
WinWait "無題-メモ帳"  ; これは、以下のWinExistで使用するための"last found window"も設定します。
Rect := Buffer(16)  ; RECTは，4つの32ビット整数（4*4=16）からなる構造体である．
DllCall("GetWindowRect", "Ptr", WinExist(), "Ptr", Rect)  ; WinExistはHWNDを返す。
L := NumGet(Rect, 0, "Int"), T := NumGet(Rect, 4, "Int")
R := NumGet(Rect, 8, "Int"), B := NumGet(Rect, 12, "Int")
MsgBox Format("Left {1} Top {2} Right {3} Bottom {4}", L, T, R, B)

構造例です。FillRect()に、一時的に赤く塗る画面の一部を示すRECT構造体のアドレスを渡す。

Rect := Buffer(16)  ; 4バイトの整数を4つ保持する容量を設定します。
NumPut( "Int", 0                  ; 左
      , "Int", 0                  ; top
      , "Int", A_ScreenWidth//2   ; right
      , "Int", A_ScreenHeight//2  ; bottom
      , Rect)
hDC := DllCall("GetDC", "Ptr", 0, "Ptr")  ;デスクトップのデバイスコンテキストを取得する場合は、0を渡す。
hBrush := DllCall("CreateSolidBrush", "UInt", 0x0000FF, "Ptr")  ; 赤のブラシ（0x0000FFはBGR形式）を作成します。
DllCall("FillRect", "Ptr", hDC, "Ptr", Rect, "Ptr", hBrush)  ; 指定された矩形を上記のブラシで塗りつぶす。
DllCall("ReleaseDC", "Ptr", 0, "Ptr", hDC)  ; クリーンアップ。
DllCall("DeleteObject", "Ptr", hBrush)  ; クリーンアップ。

構造例です。システムの時計を指定した日付と時刻に変更します。未来の日付に変更すると、スケジュールされたタスクが早期に実行される可能性があるため、注意が必要です！

SetSystemTime("20051008142211")  ; タイムスタンプを渡す（UTCではなくローカル）。

SetSystemTime(YYYYMMDDHHMISS)
; システムクロックを指定した日付と時刻に設定します。
; 呼び出し側は、入力されるパラメータが有効な日付-時間スタンプであることを確認する必要があります。
; (UTCではなく現地時間)。成功すれば0以外を、そうでなければ0を返す。
{
    ; SetSystemTime()で使用するため、パラメータをローカル時間からUTCに変換します。
    UTC_Delta := DateDiff(A_Now, A_NowUTC, "Seconds")  ; 四捨五入の関係で、「秒」の方が正確です。
    UTC_Delta := Round(-UTC_Delta/60)  ; 正確を期すため、分単位に丸めて表示します。
    YYYYMMDDHHMISS := DateAdd(YYYYMMDDHHMISS, UTC_Delta, "Minutes")  ; UTC に変換するためのオフセットを適用します。

SystemTime := Buffer(16)  ; この構造体は8個のUShortで構成されています。

NumPut( "UShort", SubStr(YYYYMMDDHHMISS, 1, 4)  ; YYYY (year)
          , "UShort", SubStr(YYYYMMDDHHMISS, 5, 2)  ; MM (month of year, 1-12)
          , "UShort", 0                             ; Unused (day of week)
          , "UShort", SubStr(YYYYMMDDHHMISS, 7, 2)  ; DD (day of month)
          , "UShort", SubStr(YYYYMMDDHHMISS, 9, 2)  ; HH (hour in 24-hour time)
          , "UShort", SubStr(YYYYMMDDHHMISS, 11, 2) ; MI (minute)
          , "UShort", SubStr(YYYYMMDDHHMISS, 13, 2) ; SS (second)
          , "UShort", 0                             ; Unused (millisecond)
          , SystemTime)

return DllCall("SetSystemTime", "Ptr", SystemTime)
}

その他の構造例

• DllCallを使用してTCP/IPサーバーにネットワーク接続し、そこからデータを受信する方法のデモについては、WinLIRCクライアントスクリプトを参照してください。
• The operating system offers standard dialog boxes that prompt the user to pick a font, color, or icon. These dialogs use structures and can be displayed via DllCall in combination with comdlg32\ChooseFont, comdlg32\ChooseColor, or shell32\PickIconDlg. Search the forums for examples.

アクティブなウィンドウを3秒間、タスクバーから削除します。同等のComCallの例と比較してみてください。

/*
  ITaskbarListのVTableにあるメソッドです：
IUnknown:
0 QueryInterface  -- ComObjQueryの代わりに使用
      1 AddRef          -- ObjAddRef の代わりに使用
      2 Release         -- ObjReleaseの代わりに使用
    ITaskbarList:
3 HrInit
      4 AddTab
      5 DeleteTab
      6 ActivateTab
      7 SetActiveAlt
*/
IID_ITaskbarList  := "{56FDF342-FD6D-11d0-958A-006097C9A090}"
CLSID_TaskbarList := "{56FDF344-FD6D-11d0-958A-006097C9A090}"

; TaskbarListオブジェクトを作成します。
tbl := ComObject(CLSID_TaskbarList, IID_ITaskbarList)

activeHwnd := WinExist("A")

DllCall(vtable(tbl.ptr,3), "ptr", tbl)                     ; tbl.HrInit()
DllCall(vtable(tbl.ptr,5), "ptr", tbl, "ptr", activeHwnd)  ; tbl.DeleteTab(activeHwnd)
Sleep 3000
DllCall(vtable(tbl.ptr,4), "ptr", tbl, "ptr", activeHwnd)  ; tbl.AddTab(activeHwnd)

; ラップされていないインターフェイスポインタは、手動で解放する必要があります。
ObjRelease(tbl.ptr)

vtable(ptr, n) {
    ; NumGet(ptr, "ptr") は、オブジェクトの仮想関数のアドレスを返します。
    ; テーブル（略してvtable）。この式の残りの部分は
    ; vtableからn番目の関数のアドレスを取得します。
    return NumGet(NumGet(ptr, "ptr"), n*A_PtrSize, "ptr")
}