MouseGetPos

마우스 커서의 현재 위치를 열람합니다. 그리고 선택적으로 어느 창과 콘트롤 위에 있는지 열람합니다.

MouseGetPos , OutputVarX, OutputVarY, OutputVarWin, OutputVarControl, Flag

매개변수

OutputVarX, OutputVarY

The names of the output variables in which to store the X and Y coordinates. 열람된 좌표는 활성 창에 상대적입니다. 단, CoordMode를 사용하여 화면 좌표를 바꾼 경우는 예외입니다.

OutputVarWin

This optional parameter is the name of the output variable in which to store the unique ID number of the window under the mouse cursor. 창을 알아낼 수 없으면, 이 변수는 비워집니다.

창은 활성화되지 않아도 탐지됩니다. 숨은 창은 탐지할 수 없습니다.

OutputVarControl

This optional parameter is the name of the output variable in which to store the name (ClassNN) of the control under the mouse cursor. 콘트롤을 결정할 수 없으면, 이 변수는 비워집니다.

콘트롤의 이름은 언제나 Window Spy로 보여지는 이름과 일치해야 합니다. 최소 [v1.0.14+]이상 요구. The window under the mouse cursor does not have to be active for a control to be detected.

Flag

If omitted or 0, the command uses the default method to determine OutputVarControl and stores the control's ClassNN. To change this behavior, add up one or both of the following digits:

1: OutputVarControl을 알아 내는 데 더 간단한 방법을 사용합니다. 이 방법은 SysEdit이나 TextPad 같은 다중 문서 인터페이스(Multiple Document Interface (MDI)) 어플리케이션에서 활성/최상위 자손 창을 올바르게 열람합니다. 그렇지만, 다른 목적으로는 정밀하지 못합니다. 예를 들어 GroupBox 콘트롤 안의 콘트롤은 제대로 탐지하지 못합니다.

2 [v1.0.43.06+]: 콘트롤의 ClassNN이 아니라 콘트롤의 HWND를 OutputVarControl에 저장합니다.

For example, to put both options into effect, the Flag parameter must be set to 3.

논평

출력 변수는 상응하는 정보가 필요하지 않으면 생략할 수 있습니다.

On systems with multiple screens which have different DPI settings, the returned position may be different than expected due to OS DPI scaling.

관련 항목

CoordMode, WinGet, SetDefaultMouseSpeed, Click

예제

MouseGetPos, xpos, ypos 
MsgBox, The cursor is at X%xpos% Y%ypos%.

#Persistent
SetTimer, WatchCursor, 100
return

WatchCursor:
MouseGetPos, , , id, control
WinGetTitle, title, ahk_id %id%
WinGetClass, class, ahk_id %id%
ToolTip, ahk_id %id%`nahk_class %class%`n%title%`nControl: %control%
return