Loop Files

Loop Files FilePattern , Mode

Loop Files, "C:\My Documents\Address List.txt"
    ShortPathName := A_LoopFileShortPath

if A_LoopFileAttrib ~= "[HRS]"  ; H（Hidden）、R（Read-only）、S（System）のいずれかに該当するファイルをスキップします。~=演算子を参照。
    continue  ; このファイルをスキップして、次のファイルに移る。

FileList := ""
Loop Files, "*.jpg"
    FileList .= A_LoopFileName "`n"
Loop Parse, FileList, "`n"
    FileMove A_LoopField, "renamed_" A_LoopField

ディレクトリとそのサブディレクトリにある各テキストファイルのフルパスを表示します。

Loop Files, A_ProgramFiles "\*.txt", "R"  ; サブフォルダへの再検索。
{
    Result := MsgBox("Filename = " A_LoopFilePath "`n`nContinue?",, "y/n")
    if Result = "No"
        break
}

フォルダーのサイズを、そのすべてのサブフォルダー内のファイルを含めて計算します。

FolderSizeKB := 0
WhichFolder := DirSelect()  ; フォルダーを選んでもらいます。
Loop Files, WhichFolder "\*.*", "R"
    FolderSizeKB += A_LoopFileSizeKB
MsgBox "Size of " WhichFolder " is " FolderSizeKB " KB."

ファイル名を名前でソートして取得します（日付でソートする場合は次の例を参照してください）。

FileList := ""  ; 空白になるように初期化します。
Loop Files, "C:\*.*"
    FileList .= A_LoopFileName "`n"
FileList := Sort(FileList, "R")  ; Rオプションは逆順にソートします。他のオプションはSortを参照。
Loop Parse, FileList, "`n"
{
    if A_LoopField = ""  ; リスト末尾の空白項目は無視します。
        continue
    Result := MsgBox("File number " A_Index " is " A_LoopField ".  Continue?",, "y/n")
    if Result = "No"
        break
}

ファイル名を更新日順に並べたものを取得します。

FileList := ""
Loop Files, A_MyDocuments "\Photos\*.*", "FD"  ; ファイルやディレクトリをインクルードします。
    FileList .= A_LoopFileTimeModified "`t" A_LoopFileName "`n"
FileList := Sort(FileList)  ; Sort by date.
Loop Parse, FileList, "`n"
{
    if A_LoopField = "" ; リスト末尾のラインフィード（空白項目）を省略します。
        continue
    FileItem := StrSplit(A_LoopField, A_Tab)  ; タブ文字で2つに分割します。
    Result := MsgBox("The next file (modified at " FileItem[1] ") is:`n" FileItem[2] "`n`nContinue?",, "y/n")
    if Result = "No"
        break
}

コピー先のファイルより新しいソースファイルのみをコピーします。この関数は、"A:\Scripts\*.ahk"のようなソースパターンと"B:\Script Backup"のような既存の保存先ディレクトリを指定して呼び出します。

CopyIfNewer(SourcePattern, Dest)
{
    Loop Files, SourcePattern
    {
        copy_it := false
        if !FileExist(Dest "\" A_LoopFileName)  ; 対象ファイルがまだ存在しない場合は常にコピーします。
            copy_it := true
        else
        {
            time := FileGetTime(Dest "\" A_LoopFileName)
            time := DateDiff(time, A_LoopFileTimeModified, "Seconds")  ; 送信元ファイルの時刻と送信先ファイルの時刻を引き算します。
            if time < 0  ; ソースファイルはデスティネーションファイルより新しい。
                copy_it := true
        }
        if copy_it
        {
            try
                FileCopy A_LoopFilePath, Dest "\" A_LoopFileName, 1   ; 上書きコピー(Yes)
            catch
                MsgBox 'Could not copy "' A_LoopFilePath '" to "' Dest '\' A_LoopFileName '".'
        }
    }
}

コマンドラインパラメーターで渡されたファイル名を、ファイルシステムに格納されているような長い名前、完全なパス、正しい大文字/小文字に変換します。

for GivenPath in A_Args  ; 各パラメータ（またはスクリプトにドロップしたファイル）に対して：
{
    Loop Files, GivenPath, "FD"  ; ファイルやディレクトリをインクルードします。
        LongPath := A_LoopFilePath
    MsgBox "The case-corrected long path name of file`n" GivenPath "`nis:`n" LongPath
}