InputHook

InputHookObj := InputHook(Options, EndKeys, MatchList)

KeyOpt

キーまたはキーのリストに対するオプションを設定します。

InputHookObj.KeyOpt(Keys, KeyOptions)

パラメータ

Keys

型：文字列

キーの一覧です。中括弧は、送信機能と同様に、キー名、仮想キーコード、スキャンコードを囲むために使用されます。例えば、{Enter}.{{}は、Enter, . および {に適用されます。キーを名前、{vkNN}、または{scNNN}で指定すると、3つの異なる結果が得られます；詳細は以下を参照してください。

Specify the string {All} (case-insensitive) on its own to apply KeyOptions to all VK and all SC, including {vkE7} and {sc000} as described below. その後、KeyOptを2回目に呼び出すと、特定のキーからオプションを削除することができます。

Specify {sc000} to apply KeyOptions to all events which lack a scan code.

Specify {vkE7} to apply KeyOptions to Unicode events, such as those sent by SendEvent "{U+221e}" or SendEvent "{Text}∞".

KeyOptions

型：文字列

以下の1文字オプションのうち1つ以上（スペースとタブは無視されます）。

-（マイナス）：-に続くオプションのうち、次の+まで削除します。

+（プラス）：それ以外の場合は、何の効果もなく、以前の-をキャンセルします。

E: End key. If enabled, pressing the key terminates Input, sets EndReason to the word EndKey and EndKey to the key's normalized name. Unlike the EndKeys parameter, the state of Shift or AltGr is ignored. 例えば、@と 2はどちらもUSキーボードレイアウトの{vk32}と同等です。

I：テキストの無視。このキーによって通常生成されるテキストはすべて無視され、キーは非テキストキーとして扱われる（VisibleNonText参照）。そのキーが通常テキストを生成しない場合、効果はありません。

N: Notify. キーが押されるたびにOnKeyDownおよびOnKeyUpコールバックが呼び出されるようにします。

S：キーを処理した後、サプレス（ブロック）します。-Sが使用されるまでは、VisibleTextまたはVisibleNonTextに優先します。+Sは -Vを意味します。

V: Visible. キーが抑制される（ブロックされる）のを防ぐ。-Vが使用されるまで、VisibleTextまたはVisibleNonTextをオーバーライドします。+Vは -Sを意味します。

備考

Options can be set by both virtual key code (VK) and scan code (SC), and are accumulative.

When a key is specified by name, options are added either by VK or by SC. 2つの物理キーが同じVKを共有し、SCによって異なる場合（Upと NumpadUpなど）、SCによって扱われます。一方、VK番号を使用する場合は、そのVKを生成するすべての物理キーに適用されます（これは、アクティブなキーボードレイアウトに依存するため、時間と共に変化する可能性があります）。

VK番号でオプションを削除しても、SCで設定されていたオプションには影響しませんし、その逆も同様です。ただし、キー名でオプションが削除され、そのキー名がVKで扱われる場合、対応するSCについてもオプションが削除されます（スクリプトのキーボードレイアウトに準じます）。これにより、すべてのキーにオプションを適用した後に、キー名を指定して除外することができます。

To prevent an option from affecting a key, the option must be removed from both the VK and the SC of that key, or sc000 if the key has no SC.

Unicode events, such as those sent by SendEvent "{U+221e}" or SendEvent "{Text}∞", are affected by options which have been set for either vkE7 or sc000. Any option applied to {All} is applied to both vkE7 and sc000, so to exclude Unicode events, remove the option from both. 事例：

InputHookObj.KeyOpt("{All}", "+I")  ; Ignore text produced by any event
InputHookObj.KeyOpt("{vkE7}{sc000}", "-I")  ; except Unicode events.

Start

入力の収集を開始します。

InputHookObj.Start()

入力がすでに進行している場合は、効果がありません。

新しく開始された入力は、InputHookスタックの最上位に置かれ、以前に開始された入力を上書きすることができます。

このメソッドは、キーボードフックをインストールします（まだインストールされていない場合）。

Stop

入力を終了し、EndReasonに Stopped という単語を設定します。

InputHookObj.Stop()

入力中でない場合は、効果がありません。

Wait

Inputが終了するまで待機する（InProgressがfalse）。

EndReason := InputHookObj.Wait(MaxTime)

パラメータ

MaxTime

型：浮動小数点数

If omitted, the wait is indefinitely. Otherwise, specify the maximum number of seconds to wait. MaxTime秒後に Input がまだ進行している場合、このメソッドは戻り、Input は終了しません。

戻り値

型：文字列

This method returns EndReason.

EndKey

Input を終了させるために押された終了キーの名前を返します。

KeyName := InputHookObj.EndKey

Note that EndKey returns the "normalized" name of the key regardless of how it was written in the EndKeys parameter. 例えば、{Esc}と {vk1B}はどちらもEscapeを生成します。GetKeyNameを使用すると、正規化された名前を取得することができます。

E オプションが使用された場合、EndKey は入力された実際の文字を返します（該当する場合）。それ以外の場合は、スクリプトのアクティブなキーボードレイアウトに従って、キー名が決定されます。

EndKey は、EndReasonが "EndKey" でない場合、空文字列を返す。

EndMods

Input終了時に論理的にダウンしていたモディファイアの文字列を返します。

Mods := InputHookObj.EndMods

すべてのモディファイアが論理的にダウン（押された）した場合、完全な文字列は次のようになります：

<^>^<!>!<+>+<#>#

これらの修飾語は、ホットキーの場合と同じ意味を持ちます。各モディファイアは必ず <（左）または > （右）で修飾されます。対応するキー名は以下の通りです：LCtrl、RCtrl、LAlt、RAlt、LShift、RShift、LWin、RWin。

InStrは、与えられた修飾語（>!や ^など）が存在するかどうかをチェックするために使用することができます。次の行で、Modsを ^!+#のような中立的な修飾語の文字列に変換することができます：

Mods := RegExReplace(Mods, "[<>](.)(?:>\1)?", "$1")

一瞬のタイミングのため、このプロパティは、Inputが終了した直後やOnEndコールバックで使用されても、GetKeyStateよりも信頼性が高い場合があります。

EndReason

Input がどのように終了したかを示すEndReason の文字列を返す。

Reason := InputHookObj.EndReason

If the Input is still in progress, an empty string is returned.

InProgress

Returns 1 (true) if the Input is in progress, otherwise 0 (false).

Boolean := InputHookObj.InProgress

Input

前回Inputを起動してから収集したテキストを返します。

String := InputHookObj.Input

このプロパティは、Inputの実行中、または終了後に使用することができます。

Match

マッチリスト入力終了の原因となった項目を返します。

String := InputHookObj.Match

This property returns the matched item with its original case, which may differ from what the user typed if the C option was omitted, or an empty string if EndReason is not "Match".

OnEnd

Input終了時に呼び出される関数オブジェクトを取得または設定します。

MyCallback := InputHookObj.OnEnd

InputHookObj.OnEnd := MyCallback

MyCallback is the function object to call. An empty string means no function object.

The callback accepts one parameter and can be defined as follows:

MyCallback(InputHookObj) { ...

Although the name you give the parameter does not matter, it is assigned a reference to the InputHook object.

You can omit the callback's parameter if the corresponding information is not needed, but in this case an asterisk must be specified, e.g. MyCallback(*).

この関数は新しいスレッドとして呼び出されるため、SendModeや DetectHiddenWindowsなどの設定にデフォルト値が設定され、新しい状態で開始されます。

OnChar

入力バッファに文字が追加された後に呼び出される関数オブジェクトを取得または設定します。

MyCallback := InputHookObj.OnChar

InputHookObj.OnChar := MyCallback

MyCallback is the function object to call. An empty string means no function object.

コールバックは2つのパラメーターを受け取り、以下のように定義できる：

MyCallback(InputHookObj, Char) { ...

パラメータに与える名前は重要ではないが、以下の値が順次割り当てられる：

1. InputHookオブジェクトへの参照。
2. A string containing the character (or multiple characters, see below for details).

対応する情報が不要な場合、コールバックのパラメータリストの最後から1つ以上のパラメータを省略することができますが、この場合、MyCallback(Param1, *)のように、最後のパラメータとしてアスタリスクを指定する必要があります。

複数の文字が存在することは、最後のキー押下の前にデッドキーが使用されていたことを示しますが、2つのキーは1つの文字に変換することができませんでした。例えば、あるキーボードレイアウトでは、`eは èを、`zは `zを出力します。

終了キーが押されても、この関数が呼び出されることはありません。

OnKeyDown

通知可能なキーが押されたときに呼び出される関数オブジェクトを取得または設定します。

MyCallback := InputHookObj.OnKeyDown

InputHookObj.OnKeyDown := MyCallback

キーダウンの通知は、まずKeyOptまたはNotifyNonTextで有効化する必要があります。

MyCallback is the function object to call. An empty string means no function object.

コールバックは3つのパラメーターを受け取り、以下のように定義できる：

MyCallback(InputHookObj, VK, SC) { ...

パラメータに与える名前は重要ではないが、以下の値が順次割り当てられる：

1. InputHookオブジェクトへの参照。
2. An integer representing the virtual key code of the key.
3. An integer representing the scan code of the key.

対応する情報が不要な場合、コールバックのパラメータリストの最後から1つ以上のパラメータを省略することができますが、この場合、MyCallback(Param1, *)のように、最後のパラメータとしてアスタリスクを指定する必要があります。

キー名を取得する場合は、GetKeyName(Format("vk{:x}sc{:x}", VK, SC))を使用することです。

この関数は新しいスレッドとして呼び出されるため、SendModeや DetectHiddenWindowsなどの設定にデフォルト値が設定され、新しい状態で開始されます。

終了キーが押されても、この関数が呼び出されることはありません。

OnKeyUp

通知可能なキーがリリースされたときに呼び出される関数オブジェクトを取得または設定します。

MyCallback := InputHookObj.OnKeyUp

InputHookObj.OnKeyUp := MyCallback

キーアップ通知は、まずKeyOptまたはNotifyNonTextで有効化する必要があります。キーが押されたときに、テキストとみなされるか非テキストとみなされるかは、キーが押されたときに判断されます。InputHookがキーダウンを検出せずにキーアップを検出した場合、非テキストとみなされます。

MyCallback is the function object to call. An empty string means no function object.

コールバックは3つのパラメーターを受け取り、以下のように定義できる：

MyCallback(InputHookObj, VK, SC) { ...

パラメータに与える名前は重要ではないが、以下の値が順次割り当てられる：

1. InputHookオブジェクトへの参照。
2. An integer representing the virtual key code of the key.
3. An integer representing the scan code of the key.

対応する情報が不要な場合、コールバックのパラメータリストの最後から1つ以上のパラメータを省略することができますが、この場合、MyCallback(Param1, *)のように、最後のパラメータとしてアスタリスクを指定する必要があります。

キー名を取得する場合は、GetKeyName(Format("vk{:x}sc{:x}", VK, SC))を使用することです。

この関数は新しいスレッドとして呼び出されるため、SendModeや DetectHiddenWindowsなどの設定にデフォルト値が設定され、新しい状態で開始されます。

BackspaceIsUndo

Backspaceが、最近押された文字をInputバッファの最後から削除するかどうかを制御します。

CurrentSetting := InputHookObj.BackspaceIsUndo

InputHookObj.BackspaceIsUndo := NewSetting

CurrentSetting is NewSetting if assigned, otherwise 1 (true) by default unless overwritten by the B option.

NewSetting is a boolean value that enables or disables this setting.

Backspaceがアンドゥとして機能する場合、テキスト入力キーとして扱われます。具体的には、キーが抑制されるかどうかは、VisibleNonTextではなく、VisibleTextに依存します。

Backspaceは、Ctrlなどの修飾キーと組み合わせて押された場合、常に無視されます（物理的な状態ではなく、論理的な修飾の状態がチェックされます）。

注：入力テキストが表示されていて（エディターなど）、その中を矢印キーなどで移動する場合、Backspaceはキャレット（挿入点）の後ろの文字ではなく、やはり最後の文字を削除します。

CaseSensitive

MatchListが大文字と小文字を区別するかどうかを制御します。

CurrentSetting := InputHookObj.CaseSensitive

InputHookObj.CaseSensitive := NewSetting

CurrentSetting is NewSetting if assigned, otherwise 0 (false) by default unless overwritten by the C option.

NewSetting is a boolean value that enables or disables this setting.

FindAnywhere

各マッチが入力テキストの部分文字列となり得るかどうかを制御します。

CurrentSetting := InputHookObj.FindAnywhere

InputHookObj.FindAnywhere := NewSetting

CurrentSetting is NewSetting if assigned, otherwise 0 (false) by default unless overwritten by the * option.

NewSetting is a boolean value that enables or disables this setting. trueの場合、ユーザーが入力した文字列の範囲内であればどこでもマッチします（マッチするのは入力テキストの部分文字列でもかまいません）。Falseの場合、ユーザーが入力した内容全体が、MatchListのフレーズのいずれかに一致しなければならない。いずれの場合も、MatchListのフレーズのうち1つは全文入力する必要があります。

MinSendLevel

収集する入力の最小送信レベルを取得または設定します。

CurrentLevel := InputHookObj.MinSendLevel

InputHookObj.MinSendLevel := NewLevel

CurrentLevel is NewLevel if assigned, otherwise 0 by default unless overwritten by the I option.

NewLevel should be an integer between 0 and 101. この値より低い送信レベルを持つイベントは無視されます。例えば、101を指定するとSendEventで生成されたすべての入力が無視され、1を指定するとデフォルトの送信レベル（0）の入力のみが無視されます。

SendInputおよびSendPlayメソッドは、この設定にかかわらず、常に無視されます。AutoHotkey以外のソースで生成された入力は、この設定の結果、決して無視されることはありません。

NotifyNonText

テキスト以外のキーが押されたときに、OnKeyDownおよびOnKeyUpコールバックを呼び出すかどうかを制御します。

CurrentSetting := InputHookObj.NotifyNonText

InputHookObj.NotifyNonText := NewSetting

CurrentSetting is NewSetting if assigned, otherwise 0 (false) by default.

NewSetting is a boolean value that enables or disables this setting. If true, notifications are enabled for all keypresses which do not produce text, such as when pressing ← or Alt+F. このプロパティを設定しても、キーのオプションには影響しません。なぜなら、テキストの生成は、キーが押された時点のアクティブウィンドウのキーボードレイアウトに依存するからです。

NotifyNonText は、VK コードが一致する前のキーダウンがテキストと非テキストのどちらに分類されるかを考慮して、キーアップイベントに適用されます。例えば、NotifyNonTextがtrueの場合、Ctrl+Aを押すと、Ctrlと Aの両方でOnKeyDownと OnKeyUpが呼び出されますが、KeyOptでそのキーに対する通知を有効にしていなければ、A単独で押してもOnKeyDownやOnKeyUpは呼ばれません。

どのキーがテキストを生成するものとしてカウントされるかの詳細については、VisibleTextを参照してください。

Timeout

タイムアウト値を秒単位で取得または設定します。

CurrentSeconds := InputHookObj.Timeout

InputHookObj.Timeout := NewSeconds

CurrentSeconds is NewSeconds if assigned, otherwise 0 by default unless overwritten by the T option.

NewSeconds is a floating-point number representing the timeout. 0 means no timeout.

通常、タイムアウトはStartが呼ばれた時点で開始されるが、Inputの実行中に本プロパティに値が代入された場合は、再開されます。タイムアウト時間が経過しても入力が継続している場合は、入力は終了し、EndReasonに Timeout という単語が設定されます。

VisibleNonText

テキストを生成しないキーまたはキーの組み合わせを表示するかどうかを制御します（ブロックされません）。

CurrentSetting := InputHookObj.VisibleNonText

InputHookObj.VisibleNonText := NewSetting

CurrentSetting is NewSetting if assigned, otherwise 1 (true) by default. The V option sets this to 1 (true).

NewSetting is a boolean value that enables or disables this setting. trueの場合、テキストを生成しないキーやキーの組み合わせは、ホットキーのトリガーになったり、アクティブウィンドウに渡されたりすることがあります。false の場合、ブロックされます。

どのキーがテキストを生成するものとしてカウントされるかの詳細については、VisibleTextを参照してください。

VisibleText

テキストを生成するキーまたはキーの組み合わせを表示するかどうかを制御します（ブロックされません）。

CurrentSetting := InputHookObj.VisibleText

InputHookObj.VisibleText := NewSetting

CurrentSetting is NewSetting if assigned, otherwise 0 (false) by default unless overwritten by the V option.

NewSetting is a boolean value that enables or disables this setting. trueの場合、テキストを生成するキーとキーの組み合わせは、ホットキーをトリガーしたり、アクティブウィンドウに渡されることがあります。false の場合、ブロックされます。

入力バッファにテキストが追加されるようなキー操作は、他のアプリケーションでは通常そうでなくても、テキストを生成したものとしてカウントされます。例えば、Ctrl+AはMオプションを使用した場合、テキストを生成し、Escは制御文字Chr(27)を生成します。

デッドキーは、通常、即効性はありませんが、テキストを生成するものとしてカウントされます。デッドキーを押すと、次のキーでも文字が出るかもしれません（デッドキーの文字だけなら）。

Backspace、アンドゥとして機能する場合のみ、テキストを生成するものとしてカウントされます。

標準の修飾キーとCapsLock、NumLock、ScrollLockは常に表示されます（ブロックされません）。

; Input OutputVar, % Options, % EndKeys, % MatchList  ; v1
ih := InputHook(Options, EndKeys, MatchList)
ih.Start()
ErrorLevel := ih.Wait()
if (ErrorLevel = "EndKey")
    ErrorLevel .= ":" ih.EndKey
OutputVar := ih.Input

MsgBox KeyWaitAny()

; また同じですが、キーをふさがないようにします。
MsgBox KeyWaitAny("V")

KeyWaitAny(Options:="")
{
    ih := InputHook(Options)
    if !InStr(Options, "V")
        ih.VisibleNonText := false
    ih.KeyOpt("{All}", "E")  ; End
    ih.Start()
    ih.Wait()
    return ih.EndKey  ; Return the key name
}

MsgBox KeyWaitCombo()

KeyWaitCombo(Options:="")
{
    ih := InputHook(Options)
    if !InStr(Options, "V")
        ih.VisibleNonText := false
    ih.KeyOpt("{All}", "E")  ; End
    ; Exclude the modifiers
    ih.KeyOpt("{LCtrl}{RCtrl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{RWin}", "-E")
    ih.Start()
    ih.Wait()
    return ih.EndMods . ih.EndKey  ; Return a string like <^<+Esc
}

WordList := "Monday`nTuesday`nWednesday`nThursday`nFriday`nSaturday`nSunday"

Suffix := ""

SacHook := InputHook("V", "{Esc}")
SacHook.OnChar := SacChar
SacHook.OnKeyDown := SacKeyDown
SacHook.KeyOpt("{Backspace}", "N")
SacHook.Start()

SacChar(ih, char)  ; Called when a character is added to SacHook.Input.
{
    global Suffix := ""
    if RegExMatch(ih.Input, "`nm)\w+$", &prefix)
        && RegExMatch(WordList, "`nmi)^" prefix[0] "\K.*", &Suffix)
        Suffix := Suffix[0]
    
    if CaretGetPos(&cx, &cy)
        ToolTip Suffix, cx + 15, cy
    else
        ToolTip Suffix

    ; ツールチップを表示している間だけ、インターセプトタブを表示します。
    ih.KeyOpt("{Tab}", Suffix = "" ? "-NS" : "+NS")
}

SacKeyDown(ih, vk, sc)
{
    if (vk = 8) ; バックスペース
        SacChar(ih, "")
    else if (vk = 9) ; タブ
        Send "{Text}" Suffix
}

ih := InputHook("L1", "{LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{RWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{CapsLock}{NumLock}{PrintScreen}{Pause}")
ih.Start()
ih.Wait()

~[::
{
    msg := ""
    ih := InputHook("V T5 L4 C", "{enter}.{esc}{tab}", "btw,otoh,fl,ahk,ca")
    ih.Start()
    ih.Wait()
    if (ih.EndReason = "Max")
        msg := 'You entered "{1}", which is the maximum length of text.'
    else if (ih.EndReason = "Timeout")
        msg := 'You entered "{1}" at which time the input timed out.'
    else if (ih.EndReason = "EndKey")
        msg := 'You entered "{1}" and terminated the input with {2}.'

    if msg  ; If an EndReason was found, skip the rest below.
    {
        MsgBox Format(msg, ih.Input, ih.EndKey)
        return
    }

    ; Otherwise, a match was found.
    if (ih.Input = "btw")
        Send("{backspace 4}by the way")
    else if (ih.Input = "otoh")
        Send("{backspace 5}on the other hand")
    else if (ih.Input = "fl")
        Send("{backspace 3}Florida")
    else if (ih.Input = "ca")
        Send("{backspace 3}California")
    else if (ih.Input = "ahk")
        Run("https://www.autohotkey.com")
}